在 Excel 中，Index函數用于返回數組或單元格區域的值或值的引用，它分為數組形式和引用形式；二者的區別在于，數組形式只能引用一個連續的區域，引用形式除可以引用一個連續的區域外還可以引用多個不連續的區域，并還可以設置返回哪個區域。

Index函數常與 Match、Small、If 、 Row 等函數配合使用，其中 Index 與 Match 配合，可以實現返回行列對應的多個值和查找滿足多個條件的值；Index 與 Small、If 、 Row 配合，可以實現一對多查找和滿足多個條件的多對多查找。

一、Excel Index函數語法

（一）數組形式

1、表達式：INDEX(Array, Row_Num, [Column_Num])

中文表達式：INDEX(數組或單元格區域, 返回行號, [返回列號])

2、說明：

A、如果 Row_Num 和 Column_Num 都大于 0，Index函數返回 Row_Num 和 Column_Num 交叉處的單元格值；如果 Column_Num 大于 0，Row_Num 為 0，返回整列；如果 Row_Num 大于 0，Column_Num 為 0，返回整行。

B、如果要以數組形式返回值，行要以水平單元格區域形式輸入，列要以垂直單元格區域形式輸入；例如：{2,3,5;6,9,12}，“2,3,5;”為一行，該行分為三列。另外，必須按 Ctrl + Shift + Enter 才能返回數組。

C、Row_Num 和 Column_Num 必須指向同一單元格，否則將返回引用錯誤 #REF!；另外，在 Excel Web App 中，不能使用數組公式。

（二）引用形式

1、表達式：INDEX(Reference, Row_Num, [Column_Num], [Area_Num])

中文表達式：INDEX(對單元格區域的引用, 返回行號, [返回列號], [返回區域號])

2、說明：

A、如果 Reference 為引用一個不連續的區域，必須用括號括起來；例如：(A1:C3,D4:E9)。

B、Area_Num 為可選項，若把它設置為 1，表示返回第一個區域；若把它設置為 2，返回第二個區域；其它的以此類推；若省略 Area_Num，則默認返回第一個區域。

C、根據公式的需要，Index函數返回一個引用或數值；例如公式 =SUM(INDEX(D2:E8,3,2)) 中的 Index函數返回對 E4 的引用；而公式=5*INDEX(D2:E8,3,2) 返回 E4 單元格中的數值，具體見下面的實例。

D、除以上幾點外，其它的與數組形式相同。

二、Excel Index函數數組形式的使用方法及實例

（一）返回行號與列號交叉單元格的實例

1、雙擊 D9 單元格，把公式 =INDEX(D2:E8,3,2) 復制到 D9，按回車，返回 528；操作過程步驟，如圖1所示：

圖1

2、公式中 D2:E8 為引用單元格區域，因為Index函數的數組形式參數 Array 既可以是數組又可以是單元格區域，第二個參數 3 為返回行號，第三個參數 2 為返回列號，由于返回行號和列號都不為 0，因此返回它們交叉單元格的值，正好是 E4；注意：返回行號與列號都從選定區域開始算起。

（二）Array為數組常量的實例

1、雙擊 A1 單元格，把公式 =INDEX({3,8,11;4,7,9},2,3) 復制到 A1，按回車，返回 9；操作過程步驟，如圖2所示：

圖2

2、公式中 {3,8,11;4,7,9} 是一個兩行三列的數組，行與行之間用半角分號（;）隔開；返回行號和列號分別為 2 和 3，也就是返回第二行第三列對應的值，恰好是 9。

（三）返回引用錯誤值 #REF! 的實例

1、雙擊 D9 單元格，把公式 =INDEX(D2:E8,2,3) 復制到 D9，按回車，返回引用錯誤值 #REF!；操作過程步驟，如圖3所示：

圖3

2、公式引用區域 D2:E8 只有兩行兩列，而返回列號為 3，也就是引用了不存在的列，因此返回引用錯誤。

三、Excel Index函數引用形式的使用方法及實例

（一）引用多個不連續區域的實例

1、雙擊 B10 單元格，把公式 =INDEX((B2:C4,D6:E9),2,1,2) 復制到 B10，按回車，返回 921；操作過程步驟，如圖4所示：

圖4

2、公式中的單元格引用區域 (B2:C4,D6:E9) 為兩個不連續的區域，因此要用括號括起來；返回區域號參數 Area_Num 為 2，即返回第二個區域，返回行號和列號分別為 2 和 1，即返回 D6:E9 區域的第二行第一列，也就是 D7。

（二）省略參數 Area_Num 的實例

1、雙擊 B10 單元格，把公式 =INDEX((B2:C4,D6:E9),2,1) 復制到 B10，按回車，返回 571；再次雙擊 B10，把“,D6:E9) 和一個左括 (”去掉，公式變為 =INDEX(B2:C4,2,1)，按回車，仍然返回 571；操作過程步驟，如圖5所示：

圖5

2、公式 =INDEX((B2:C4,D6:E9),2,1) 省略了參數 Area_Num，默認選擇第一個區域 B2:C4，再返回該區域第二行第一列對應的單元格 B3；而公式 =INDEX(B2:C4,2,1) 與數組形式一樣。

（三）返回對單元格引用的實例

1、雙擊 E9 單元格，把公式 =SUM(INDEX(D2:E8,3,2)) 復制到 E9，按回車，返回 528；按住 Alt，依次按一次 M、V，打開“公式求值”窗口，單擊“求值”，公式變為 SUM($E$4)，說明Index函數返回的是對 E4 的引用；操作過程步驟，如圖6所示：

圖6

2、SUM($E$4) 表示對 E4 求和，$E$4 表示對 E4 單元格的絕對引用。

（四）返回引用單元格的值實例

1、雙擊 E9 單元格，把公式 =5*INDEX(D2:E8,3,2) 復制到 E9，按回車，返回 2640；按住 Alt，依次按一次 M、V，打開“公式求值”窗口，按回車“求值”，公式變為 5 * 528，說明Index函數返回引用單元格的值；操作過程步驟，如圖7所示：

圖7

2、從以上兩例可知，Index函數可以根據公式的實際需求返回對單元格引用或單元格中的值。

（五）Index + Sum函數組合返回整行或整列的實例

1、把公式 =SUM(INDEX(B2:E9, 2, 0)) 復制到 E10 單元格，按回車，返回 1601；按住 Alt，依次按一次 M、V，打開“公式求值”窗口，按回車“求值”，公式變為 SUM($B$3:$E$3)，B3:E3 正是選定區域的第二行。雙擊 E10，把公式改為 =SUM(INDEX(B2:E9, 0, 3))，按回車，返回 5123，同樣方法打開“公式求值”窗口，按回車，公式變為為 SUM($D$2:$D$9)， D2:D9 正是選定區域的第三列；操作過程步驟，如圖8所示：

圖8

2、Index函數返回整行或整列通常根據公式需要返回，僅輸入單一的Index公式通常無法返回。

四、Excel Index函數的擴展應用

（一）Index + Match函數組合返回行列對應的多個值

1、假如要返回每個月各類服裝的銷量。雙擊 B12 單元格，把公式 =INDEX($A$1:$E$9, MATCH($A12,$A$1:$A$9,), MATCH(B$11,$A$1:$E$1,)) 復制到 B12，按回車，返回 567；選中 B12，把鼠標移到 B12 右下角的單元格填充柄上，鼠標變為十字架后，按住左鍵，往右拖，一直拖到 E12，則所經過單元格都返回相應銷量；把鼠標移到 E12 右下角的單元格填充柄上，往下拖，則返回“3月和6月”的服裝銷量；操作過程步驟，如圖9所示：

圖9

2、公式 =INDEX($A$1:$E$9,MATCH($A12,$A$1:$A$9,),MATCH(B$11,$A$1:$E$1,)) 說明：

A、$A$1 是對行和列的絕對引用，往下拖，A1 不會變為 A2、A3、……；往右拖，A1 不會變為 B1、C1、……。$A$1:$A$9 以數組形式返回 A1 至 A9 的數據。

B、MATCH($A12,$A$1:$A$9,) 在 A1 至 A9 中查找 A12（1月），返回 A12 在 A1:A9 中的位置 2；Match函數省略了最后一個參數，默認選擇 1，即返回小于等于查找值的最大值。

C、MATCH(B$11,$A$1:$E$1,) 在 A1 至 E1 中查找 B11（T恤），返回位置也為 2。

D、則公式變為 =INDEX($A$1:$E$9,2,2)，即在 A1:E9 中返回第二行第二列對應的單元格 B2 中的值，即 567。

提示：如果拖出的數據相同，按 Ctrl + C 保存即可。

（二）Index + Match函數組合實現查找滿足多個條件的值

1、假如要查找“分類”為“男裝”且“價格為 80 的服裝名稱。雙擊 C11 單元格，把公式 =INDEX(B2:D8,MATCH(A11&B11,C2:C8&D2:D8,),1) 復制到 C11，按 Ctrl + Shift + 回車，返回“黑色T恤”；操作過程步驟，如圖10所示：

圖10

2、公式 =INDEX(B2:D8,MATCH(A11&B11,C2:C8&D2:D8,),1) 說明：

A、公式是一個數組公式，因此要按 Ctrl + Shift + 回車。

B、A11&B11 是把 A11 與 B11 連接起來，C2:C8&D2:D8 是把 C2:C8 和 D2:D8 每行對應的值連結起來，例如 C2&D2、C3&D3。

C、則 MATCH(A11&B11,C2:C8&D2:D8,) 變為 MATCH("男裝80",{"女裝38.8";"女裝55.8";"女裝79.9";"女裝80";"女裝82";"男裝80";"男裝198"},)，接著在數組中查找“男裝80”，找到后返回它在數組中的位置 6。

D、則公式變為 =INDEX(B2:D8,6,1)，最后在 B2:D8 中返回第六行第一列交叉的單元格中的值，即 B7 中的“黑色T恤”。

（三）Index + Small + IF + Row函數組合實現一對多查找

1、假如要查找“銷售部”的所有員工姓名和職務。雙擊 F2 單元格，把公式 =IFERROR(INDEX(A:A,SMALL(IF(B$2:B$8=$E$2,ROW($2:$8),4^8),ROW(A1))),"") 復制到 F2，按 Ctrl + Shift + 回車，返回“林語彤”；選中 F2，往下拖，按 Ctrl + S 保存，則返回“銷售部”的其他員工姓名；雙擊 G2，把上面的公式復制到 G2，并把公式中的 A:A 改為 C:C，按 Ctrl + Shift + 回車，返回“員工”，同樣用往下拖的方法返回其他員工職務；操作過程步驟，如圖11所示：

圖11

2、公式 =IFERROR(INDEX(A:A,SMALL(IF(B$2:B$8=$E$2,ROW($2:$8),4^8),ROW(A1))),"") 說明：

A、B$2:B$8 以數組形式返回 B2 至 B8 中的元素，即 {"銷售部";"行政部";"銷售部";"財務部";"行政部";"銷售部";"財務部"}；$E$2 為“銷售部”；則 B$2:B$8=$E$2 變為 {"銷售部";"行政部";"銷售部";"財務部";"行政部";"銷售部";"財務部"}="銷售部"，接著，用數組中的每個元素與“銷售部”比較，如果相等返回 True，否則返回 False，最后返回 {TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE}。

B、ROW($2:$8) 以數組形式返回 2 到 8 之間的數值，即 {2;3;4;5;6;7;8}；4^8 是求 4 的 8 次方，結果為 65536（是 Excel 支持的最大值）。

C、則IF(B$2:B$8=$E$2,ROW($2:$8),4^8) 變為 IF({TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE},{2;3;4;5;6;7;8},65536)，接著，從條件數組中取出第一個元素 TRUE，由于它為真，所以返回 If 第二個參數中的值，即返回數組 {2;3;4;5;6;7;8} 中與條件數組對應的元素 2；第二次從條件數組中取出第二個元素 FALSE，由于它為假，所以返回 If 第三個參數，即返回 65536；最后返回 {2;65536;4;65536;65536;7;65536}。

D、ROW(A1) 返回 A1 的行號 1；則 SMALL(IF(B$2:B$8=$E$2,ROW($2:$8),4^8),ROW(A1)) 變為 SMALL({2;65536;4;65536;65536;7;65536},1)，接著，用 Small 在數組中查找第 1 個小值，也就是 2。

E、則公式變為 =IFERROR(INDEX(A:A,2),"")，A:A 表示引用 A 列，最后在 A 列中返回第二行的值，即返回 A2 中的值“林語彤”；IfError 用于錯誤處理，如果 INDEX(A:A,2) 返回錯誤，則返回空，否則返回 INDEX(A:A,2) 的返回值。

提示：如果要查找其它部門的員工，把 E2 中的“銷售部”改為其它部門按回車即可，如果沒有變化，只需按 Ctrl + S 保存。如果要把返回的值全顯示到一行，例如把“銷售部”的員工顯示到一行，只需把公式中的 ROW(A1) 改為 COLUMN(A1)，則公式變為 =IFERROR(INDEX(A:A,SMALL(IF(B$2:B$8=$E$2,ROW($2:$8),4^8),COLUMN(A1))),"")，往右拖即可。

（四）Index + Small + IF + Row函數組合實現多條件多對多查找

1、假如要查找所有女裝且價格為 80 的服裝名稱。雙擊 C11 單元格，把公式 =IFERROR(INDEX(B:B,SMALL(IF((C$2:C$8=$A$11)*(D$2:D$8=$B$11),ROW($2:$8),4^8),ROW(A1))),"") 復制到 C11，按 Ctrl + Shift + 回車，返回“粉紅襯衫”；用往下拖的方法返回其它符合條件的服裝名稱；操作過程步驟，如圖12所示：

圖12

2、公式與上面的 Index + Small + IF + Row函數組合公式一樣，所不同的只是 If 的條件由多個表達式組成，每個表達式之間用星號（*）連接，表示“與”的關系，即要同時滿足多個條件。